作業を効率化させるExcel VBA Tips集 VBAから作業中のブックをバックアップする

作業を楽にする為の苦労を惜しまない、本末転倒なプログラマーが実際に業務で使ったExcel VBAのサンプルを公開しています。掲載しているサンプルは関数単位ですので、部品化しやすいと思います。

VBAから作業中のブックをバックアップする

Excelで設計書などを作成している場合、
定期的にバックアップしたくなります。

おそらく、以下のような手順で行われると思います。

１．作業中のブックを上書き保存
　↓
２．マイコンピュータより、１のファイルをコピーする
　↓
３．ファイル名を適当な名前にリネームする

下記に紹介するVBAをツールバーに登録したり、ショートカットキーに割り当てていれば、
ボタン一つで、バックアップが作成できるので、上記１～３の手順を１つの動作で行えます。

VBAの処理概要は以下の通りです。
①作業中のブックを上書き保存
②日付時刻を付加したファイル名文字列を作成する
③作業中ブックを②のファイル名でコピーする

と、いたってシンプルな構成です。

'--------------------------------------------------------------------
' 関数名 : BackupThisBook
' 機能   : 作業中ブックを同ディレクトリにバックアップ
' 引数   : なし
' 戻り値 : なし
' 作成日 : 2008/03/29
' 作成者 : lily(http://vbatips.blog37.fc2.com/)
'--------------------------------------------------------------------
Sub BackupThisBook()
Dim wb As Workbook
Dim ret As Integer
Dim sFileName As String
Dim sNowTime As String

    '確認メッセージ
    ret = MsgBox("バックを作成しますか？作業中ブックを保存します。", vbYesNo)
    If ret = vbNo Then
        Exit Sub
    End If
    
    'アクティブブック取得
    Set wb = ActiveWorkbook

    'アクティブブックの編集確認
    If wb.Saved = False Then
        '編集有りの場合は上書き保存を行う
        wb.Save
    End If

    '現在時刻を取得する
    sNowTime = CStr(Format(Date, "yymmdd")) & CStr(Format(Time, "hhmmss"))

    'コピー先のファイル名作成（フルパス）
    sFileName = wb.Path & "\" & sNowTime & "_" & wb.Name

    'コピー作成
    wb.SaveCopyAs sFileName

    MsgBox "バックアップ完了"

End Sub